COMMENT ⊗   VALID 00014 PAGES
C REC  PAGE   DESCRIPTION
C00001 00001
C00002 00002
C00003 00003
C00005 00004
C00007 00005	cmchar "Calligraphic L"
C00012 00006	cmchar "Calligraphic M"
C00016 00007	cmchar "Calligraphic N"
C00018 00008
C00022 00009
C00035 00010
C00038 00011
C00042 00012
C00043 00013
C00044 00014
C00046 ENDMK
C⊗;
cmchar "Calligraphic L";
beginchar("L",10.8u#,cap_height#,0);
italcorr .2h#*slant+.5u#;
adjust_fit(0,0); pickup cal.nib;
x1=.2w; x2=x1+.3w; rt x3=x2+.25w; lft x4=0;
x5=.8[x4,x6]; rt x6=w; x7=.2[x4,x5];
y1=.4h; top y2=h+o; y3=.8h; bot y4=bot y5=0; y6=.2h; y7=9/70h;
path p; p=z4...z7{right}..{right}z5...{up}z6;
draw p;	% arm
draw z4{dir .75angle(direction 0 of p)}
 ...z1{up}...z2{right}...{down}z3;	% stem and flourish
math_fit(.5u#,ic#); labels(1,2,3,4,5,6,7); endchar;
cmchar "Calligraphic M";
beginchar("M",19.8u#,cap_height#,0);
italcorr max(h#*slant-u#,.75cap_curve#)+.5cap_curve#+.5u#;
adjust_fit(-.1w#,0); pickup cal.nib;
top z5-z4=top z11-z10=penoffset left of pen_[upright_cal.nib];
z6=.3[z7,z5]-bend; z9=.3[z8,z10]+.5bend; z12=.3[z13,z11]-bend;
x7=.5[x2,x13]; bot y7=.05h; x13=w; bot y13=bot_flourish_line; z7=z8;
pickup upright_cal.nib;
lft x1=.1w; x2=.2w; x4=.2[x2,x7]; x10=.8[x7,x13];
y1=.05h+y2; bot y2=bot_flourish_line; top y4=top y10=h+.5cap_curve;
z3=whatever[z2,z4]+2bend; y3=y6;
draw (z1..tension1.2..{right}z2) soft flex(z2,z3,z4);	% left stem
draw flex(z8,z9,z10);	% right diagonal
pickup cal.nib;
erase fill (0,bot y5)--(w,bot y5)--(w,top y5)--(0,top y5)--cycle;
draw flex(z5,z6,z7);	% left diagonal
draw flex(z11,z12,z13) soft (z13--z13+cal.extension);	% right stem
math_fit(.5u#-.05h#*slant,ic#); labels(1,2,3,4,5,6,7,8,9,10,11,12,13); endchar;
cmchar "Calligraphic N";
beginchar("N",9u#,cap_height#,0);
italcorr h#*slant+.5u#;
adjust_fit(2u#,3u#); pickup cal.nib;
top z5=z4+penoffset left of pen_[upright_cal.nib];
z6=.3[z7,z5]-bend; rt z7=(w,0);
pickup upright_cal.nib;
lft x1=x2-2u; x2=-u; x4=0; rt x8=w; x10=w; rt x11=w+3u;
y1=y2+.05h; bot y2=bot_flourish_line; top y4=h+.5cap_curve;
y3=y6; z3=whatever[z2,z4]+2bend;
y8=0; y10=h; z9=.7[z8,z10]-.5bend; bot y11=h;
draw (z1..tension1.2..{right}z2) soft flex(z2,z3,z4);	% left stem
draw flex(z8,z9,z10)...{right}z11;	% right stem
pickup cal.nib;
erase fill (-4u,bot y5)--(.5w,bot y5)--(.5w,top y5)--(-4u,top y5)--cycle;
draw flex(z5,z6,z7);	% diagonal
math_fit(.5u#-.05h#*slant,.5h#*slant);
labels(1,2,3,4,5,6,7,8,9,10,11); endchar;